mkfontdir under DECwindows

[Gary Barnes]

Here is a fragment of a DCL command file that we use to install a program
that requires special fonts on VMS.  It locates the .bdf files in the default
directory, compiles them using the font compiler, and then copies them into
the fonts directory.  Just reboot after that and you are set.

Check Appendix A of the Guide to Xlib Programming; MIT C Binding for what
little information seems to be available.

	Gary

$!--Fonts usable by the server go here.
$!  Use one of the User_* elements in the search path named DECW$FONT:.
$!  The one you use is determined by the type of screen you have.  DECW$FONT
$!  should already be set up for your hardware so just use the one mentioned
$!  there.
$!	SHOW LOGICAL/TABLE=DECW$SERVER0_TABLE DECW$FONT
$
$    FONTDIR     := SYS$COMMON:[SYSFONT.DECW.USER_75DPI]
$!   FONTDIR     := SYS$COMMON:[SYSFONT.DECW.USER_100DPI]
$
$!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
$! Install the fonts
$!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
$
$ Next_Font :
$    NAME = f$search( "*.bdf" )
$    if NAME .eqs. "" then goto Fonts_Compiled
$	CMD = "font " + NAME + "/minbox"
$	write/symbol sys$output CMD
$	CMD
$	NAME = f$parse(NAME, , , "NAME") + ".DECW$FONT"
$	CMD = "copy " + NAME + " " + FONTDIR + NAME
$	write/symbol sys$output CMD
$	CMD
$    goto Next_Font
$ Fonts_Compiled :
$    CMD = "delete *.DECW$FONT;*"
$    write/symbol sys$output CMD
$    CMD
$    type sys$input
*******************************************************************************
* You will have to reboot any DECwindows machines that share this font        *
* directory before those machines will be able to successfully use the new    *
* fonts.  You may also wish to purge the font directory.  Note that purging   *
* old versions of fonts may cause running servers to be unable to find those  *
* fonts because the DECwindows server remembers not only file names but also  *
* version numbers.  A reboot causes a server to use the latest versions.      *
*******************************************************************************
$    return
$